{
  lib,
  fetchFromGitHub,
  php,
  majorVersion,
}: let
  versions = {
    "9" = {
      version = "9.6.25";
      hash = "sha256-DKbInG8zsIa2DFNY5eqW8CKWUhGM0yc3/wppUiizYbg=";
      vendorHash = "sha256-pvP2ULwnDbPb9bIaNKkQ7cvyMpgZiFfoJfUFRGzojBQ=";
    };
    "10" = {
      version = "10.5.46";
      hash = "sha256-DtQ6CR4RAGKpZcJA9WZ5ud5ztIBTr8MeVTIhFwbGHYc=";
      vendorHash = "sha256-fNv9pWFwYTyw3KEGtmbKNzXFsiDE6oZjRCWhypa/k0A=";
    };
    "11" = {
      version = "11.5.22";
      hash = "sha256-oXoh/2G0bqPPyvVoQUUdUz8XGyNtRJE3taUFGu2UIsc=";
      vendorHash = "sha256-9gLTJe2ft90qGr/d8/Zc/ua7EWyNZ16wPEZRe9sKZf0=";
    };
    "12" = {
      version = "12.2.1";
      hash = "sha256-D5WI1kv05L8X3Gfw/MCxGdIcqWyWJg68GL9I24z/zIY=";
      vendorHash = "sha256-H+XMRMvbUz/WCUdPRmL8nSCqa5YE3Qb1+goEQjjDK70=";
    };
  };
in
  php.buildComposerProject2 (finalAttrs: {
    pname = "phpunit";
    inherit (versions.${majorVersion}) version vendorHash;

    src = fetchFromGitHub {
      owner = "sebastianbergmann";
      repo = "phpunit";
      tag = finalAttrs.version;
      inherit (versions.${majorVersion}) hash;
    };

    doInstallCheck = false;

    meta = {
      changelog = "https://github.com/sebastianbergmann/phpunit/blob/${finalAttrs.version}/ChangeLog-${lib.versions.majorMinor finalAttrs.version}.md";
      description = "PHP Unit Testing framework";
      homepage = "https://phpunit.de";
      license = lib.licenses.bsd3;
      mainProgram = "phpunit";
      maintainers = with lib.maintainers; [onny];
      teams = [lib.teams.php];
    };
  })