haze/flake.nix

{
  inputs = {
    nixpkgs.url = "nixpkgs/nixos-26.05";
    flakelight = {
      url = "github:nix-community/flakelight";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    mill-scale = {
      url = "git+https://codeberg.org/icewind/mill-scale.git";
      inputs.flakelight.follows = "flakelight";
    };
    phps = {
      url = "github:fossar/nix-phps";
    };
    nix2container = {
      url = "github:nlewo/nix2container";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };
  outputs =
    {
      nix2container,
      mill-scale,
      phps,
      ...
    }:
    mill-scale ./. {
      crossTargets = [
        "x86_64-unknown-linux-gnu"
        "x86_64-unknown-linux-musl"
        "aarch64-unknown-linux-gnu"
        "aarch64-unknown-linux-musl"
      ];

      nixpkgs.config = {
        allowUnfree = true;
      };

      extraPaths = [
        ./certificates
      ];

      withOverlays = [
        (import ./nix/overlay.nix)
        (final: prev: {
          inherit (phps.packages.${prev.system}) php81 php80;
          inherit (nix2container.packages.x86_64-linux) nix2container;
          blackfire = prev.blackfire.overrideAttrs (
            oldAttrs: finalAttrs: {
              src = final.fetchurl {
                url = "https://packages.blackfire.io/debian/pool/any/main/b/blackfire/blackfire_${finalAttrs.version}_amd64.deb";
                sha256 = "sha256-1fswfZEElLyXWqvNW76BpKTpBomK9cglJtitZgcpxhM=";
              };
            }
          );
        })
      ];

      packages = {
        "haze-image-php-8.5" = pkgs: pkgs.haze-image-php-85;
        "haze-image-php-8.4" = pkgs: pkgs.haze-image-php-84;
        "haze-image-php-8.3" = pkgs: pkgs.haze-image-php-83;
        "haze-image-php-8.2" = pkgs: pkgs.haze-image-php-82;
        "haze-image-php-8.1" = pkgs: pkgs.haze-image-php-81;
        "haze-image-php-8.0" = pkgs: pkgs.haze-image-php-80;
      };

      tools =
        pkgs: with pkgs; [
          cargo-edit
          bacon
          skopeo
          dive
        ];

      homeModules = {
        default =
          {
            pkgs,
            config,
            lib,
            ...
          }:
          {
            imports = [ ./nix/hm-module.nix ];
            config = lib.mkIf config.programs.haze.enable {
              programs.haze.package = lib.mkDefault pkgs.haze;
            };
          };
      };
    };
}