flake update

nix/module.nix

@@ -0,0 +1,91 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+with lib; let
+  cfg = config.services.mitemp;
+  format = pkgs.formats.toml {};
+  configFile = format.generate "mitemp-config.toml" {
+    inherit (cfg) names;
+    listen = {
+      inherit (cfg) socket;
+    };
+  };
+in {
+  options.services.mitemp = {
+    enable = mkEnableOption "mitemp";
+
+    names = mkOption {
+      type = types.attrs;
+      default = {};
+      description = "Names for mitemp sensors";
+    };
+
+    socket = mkOption {
+      type = types.str;
+      default = "/run/mitemp/mitemp.sock";
+      description = "socket to listen on";
+    };
+
+    package = mkOption {
+      type = types.package;
+      defaultText = literalExpression "pkgs.mitemp-prometheus";
+      description = "package to use";
+    };
+  };
+
+  config = mkIf cfg.enable {
+    users.users.mitemp = {
+      isSystemUser = true;
+      group = "mitemp";
+    };
+    users.groups.mitemp = {};
+
+    services.dbus.packages = [cfg.package];
+    systemd.services."mitemp" = {
+      wantedBy = ["multi-user.target"];
+      after = ["dbus.service"];
+
+      serviceConfig = {
+        ExecStart = "${cfg.package}/bin/mitemp-prometheus ${configFile}";
+
+        Restart = "on-failure";
+        User = "mitemp";
+        PrivateTmp = true;
+        ProtectSystem = "strict";
+        ProtectHome = true;
+        NoNewPrivileges = true;
+        ProtectClock = true;
+        CapabilityBoundingSet = true;
+        ProtectKernelLogs = true;
+        ProtectControlGroups = true;
+        SystemCallArchitectures = "native";
+        ProtectKernelModules = true;
+        RestrictNamespaces = true;
+        MemoryDenyWriteExecute = true;
+        ProtectHostname = true;
+        LockPersonality = true;
+        ProtectKernelTunables = true;
+        RestrictAddressFamilies = ["AF_UNIX"];
+        RuntimeDirectory = "mitemp";
+        RestrictRealtime = true;
+        ProtectProc = "invisible";
+        SystemCallFilter = ["@system-service" "~@resources" "~@privileged"];
+        IPAddressDeny = "any";
+        PrivateUsers = true;
+        ProcSubset = "pid";
+        RemoveIPC = true;
+        PrivateDevices = true;
+        RestrictSUIDSGID = true;
+        BindPaths = ["/run/dbus"];
+      };
+
+      confinement = {
+        enable = true;
+        binSh = null;
+      };
+    };
+  };
+}

nix/overlay.nix

@@ -0,0 +1,3 @@
+final: prev: {
+  mitemp-prometheus = final.callPackage ./package.nix {};
+}

nix/package.nix

@@ -0,0 +1,37 @@
+{
+  stdenv,
+  rustPlatform,
+  lib,
+  pkg-config,
+  dbus,
+}: let
+  inherit (lib.sources) sourceByRegex;
+  inherit (builtins) fromTOML readFile;
+  src = sourceByRegex ../. ["Cargo.*" "(src)(/.*)?"];
+  cargoToml = (fromTOML (readFile ../Cargo.toml)).package;
+in
+  rustPlatform.buildRustPackage rec {
+    pname = cargoToml.name;
+
+    inherit src;
+    inherit (cargoToml) version;
+
+    buildInputs = [
+      dbus
+    ];
+
+    nativeBuildInputs = [
+      pkg-config
+    ];
+
+    preInstall = ''
+      mkdir -p $out/share/dbus-1/system.d
+      cp ${../dbus-bluetooth.xml} $out/share/dbus-1/system.d/dbus-bluetooth.conf
+    '';
+
+    cargoLock = {
+      lockFile = ../Cargo.lock;
+    };
+
+    meta.mainProgram = "mitemp-prometheus";
+  }