nix module

flake.nix

@@ -11,5 +11,28 @@
     };
   };
   outputs = {mill-scale, ...}:
-    mill-scale ./. {};
+    mill-scale ./. {
+      withOverlays = [
+        (import ./nix/overlay.nix)
+      ];
+
+      packages = {
+        single-file-server = pkgs: pkgs.single-file-server;
+      };
+
+      nixosModules = {outputs, ...}: {
+        default = {
+          pkgs,
+          config,
+          lib,
+          ...
+        }: {
+          imports = [./nix/module.nix];
+          config = lib.mkIf config.services.single-file-server.enable {
+            nixpkgs.overlays = [outputs.overlays.default];
+            services.single-file-server.package = lib.mkDefault pkgs.single-file-server;
+          };
+        };
+      };
+    };
 }

nix/module.nix

@@ -0,0 +1,96 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+with lib; let
+  format = pkgs.formats.toml {};
+  cfg = config.services.single-file-server;
+  configFile = format.generate "single-file-server.toml" {
+    single-file.executable = "${cfg.singleFilePackage}/bin/single-file";
+    browser.executable = getExe cfg.browserPackage;
+  };
+in {
+  options.services.single-file-server = {
+    enable = mkEnableOption "Enables the single-file-server service";
+
+    socket = mkOption rec {
+      type = types.str;
+      default = "/run/single-file-server/single-file.sock";
+      description = "The socket to listen on";
+    };
+
+    singleFilePackage = mkOption {
+      type = types.package;
+      default = pkgs.single-file-cli;
+      description = "single-file-cli package to use";
+    };
+
+    browserPackage = mkOption {
+      type = types.package;
+      default = pkgs.chromium;
+      description = "browser package to use";
+    };
+
+    package = mkOption {
+      type = types.package;
+      description = "package to use";
+    };
+
+    logLevel = mkOption {
+      type = types.str;
+      default = "info";
+      description = "Log level";
+    };
+  };
+
+  config = mkIf cfg.enable {
+    systemd.services.single-file-server = {
+      wants = ["single-file-server.socket"];
+      after = ["single-file-server.socket"];
+      environment = {
+        RUST_LOG = cfg.logLevel;
+      };
+
+      serviceConfig = {
+        Restart = "on-failure";
+        ExecStart = "${getExe cfg.package} --config ${configFile}";
+        DynamicUser = true;
+        PrivateUsers = true;
+        PrivateTmp = true;
+        ProtectSystem = "strict";
+        ProtectHome = true;
+        NoNewPrivileges = true;
+        ProtectClock = true;
+        CapabilityBoundingSet = true;
+        ProtectControlGroups = true;
+        SystemCallArchitectures = "native";
+        ProtectKernelModules = true;
+        ProtectKernelLogs = true;
+        ProtectKernelTunables = true;
+        ProtectHostname = true;
+        LockPersonality = true;
+        ProtectProc = "invisible";
+        PrivateDevices = true;
+        RestrictAddressFamilies = ["AF_LOCAL" "AF_INET" "AF_INET6"];
+        RestrictRealtime = true;
+        SystemCallFilter = ["~@reboot" "~@cpu-emulation" "~@obsolete" "~@debug" "~@swap" "~@clock" "~@module"];
+        RestrictNamespaces = ["~cgroup"];
+        IPAddressDeny = ["10.0.0.0/8" "172.16.0.0" "192.168.0.0"];
+        UMask = "0007";
+        RuntimeDirectory = "single-file-server";
+      };
+    };
+
+    systemd.sockets.single-file-server = {
+      enable = true;
+      wantedBy = ["sockets.target"];
+
+      socketConfig = {
+        ListenStream = cfg.socket;
+        SocketMode = "0666";
+      };
+    };
+  };
+}

nix/overlay.nix

@@ -0,0 +1,3 @@
+final: prev: {
+  single-file-server = final.callPackage ./package.nix {};
+}

nix/package.nix

@@ -0,0 +1,21 @@
+{
+  rustPlatform,
+  pkg-config,
+  lib,
+}: let
+  inherit (lib.sources) sourceByRegex;
+  inherit (builtins) fromTOML readFile;
+  src = sourceByRegex ../. ["Cargo.*" "(src)(/.*)?"];
+  version = (fromTOML (readFile ../Cargo.toml)).package.version;
+in
+  rustPlatform.buildRustPackage rec {
+    pname = "single-file-server";
+
+    inherit src version;
+
+    cargoLock = {
+      lockFile = ../Cargo.lock;
+    };
+
+    meta.mainProgram = "single-file-server";
+  }